Choice definition | Developer Documentation

Usage

choice {
      field-name₁: element-definition₁
      ...
      field-name_n: element-definition_n
      }

Parameters

Parameter	Description
field-name (required)	The workflow script identifier of the field.
element-definition (required)	An element definition.

Remarks

When accessing the items in a list of choice element in a workflow script, the script first needs to determine which of the available element choices the given list item is. Use the list-of-choice-parent.hasname-of-choice-element() method inside an if statement to do this.

Similarly, when populating a list of choice element in a workflow script, apart from the value for the new list item, the script also needs to declare which of the available types the new list item is. Use the [Name]New() method to do this.

Samples

list of choice sample

Integration message schema

listOfChoice.dacsem

schema listOfChoice meta listOfChoice namespace "http://schemas.rockyjupiter.com/listOfChoice"
epsilon: element {
  zetaeta: list of choice {
    zeta: element of type int;
    eta: element {
      theta: attribute of type string;
    }
  }
}

Sample schema-conformant XML

listOfChoice.xml

<epsilon>
  <zeta>5</zeta>
  <eta theta="shrubbery"/>
  <zeta>7</zeta>
  <zeta>13</zeta>
  <eta theta="Ni!"/>
</epsilon>

Accessing a list element and its attribute inside a list of choice in a workflow script

listOfChoiceRead.rfs

server program listOfChoiceRead for dacs listOfChoice
{
  var zetaeta = dacs.epsilon.zetaeta;
  foreach(var ze in zetaeta)
  {
    if(ze.haszeta)
    {
      trace ze.zeta;
    }
    else
    {
      trace ze.eta.theta;
    }
  }
}

Creating list elements inside a list of choice in a workflow script

Download the mopey.fls.xml trigger form for the script below.

listOfChoiceWrite.rfs

server program listOfChoiceWrite for form mopey
using dacs listOfChoice;
{
  var msg = messages.listOfChoice.New();
  var zetaeta = msg.epsilon.zetaeta.AddNew();
  var pauli = zetaeta.etaNew();
  zetaeta.zeta = 86;
  pauli.theta = "Holy Grail";
}

optional wrapped list of choice sample

Integration message schema

optionalChoice.dacsem

schema 'optionalChoice' meta 'optionalChoice' namespace "http://schemas.rockyjupiter.com/optionalChoice"
alpha: element {
  betagamma: optional wrapped list of choice {
    beta: element of type int;
    gamma: element {
      delta: attribute of type string;
    }
  }
}

Sample schema-conformant XML

optionalChoice.xml

<alpha>
  <betagamma>
    <beta>5</beta>
    <gamma delta="shrubbery"/>
    <beta>7</beta>
    <beta>13</beta>
    <gamma delta="Ni!"/>
  </betagamma>
</alpha>

Accessing a list element and its attribute inside an optional list of choice in a workflow script

optionalChoiceRead.rfs

server program optionalChoiceRead for dacs optionalChoice
{
  if(dacs.alpha.betagamma != null)
  {
    foreach(var bg in dacs.alpha.betagamma)
    {
      if(bg.hasbeta)
      {
        trace bg.beta;
      }
      else
      {
        trace bg.gamma.delta;
      }
    }
  }
}

Creating list elements inside an optional list of choice element in a workflow script

Download the pokey.fls.xml trigger form for the script below.

optionalChoiceWrite.rfs

server program optionalChoiceWrite for form pokey
using dacs optionalChoice;
{
  var msg = messages.optionalChoice.New();
  var betagamma = msg.alpha.betagammaNew();
  var schroedinger = betagamma.AddNew();
  schroedinger.beta = 7;
  var heisenberg = betagamma.AddNew();
  heisenberg.gammaNew().delta = "Pauli";
}